
Exile is a powerful Elixir library for running external programs with proper back-pressure and streaming capabilities. Think of it as Ports done right - giving you fine-grained control over input/output streams while preventing memory issues.
Key Features
	Stream-based API with proper back-pressure
	Memory-efficient handling of large outputs
	Selective control over stdin/stdout/stderr
	Clean process management (no zombies!)
	No external dependencies or middleware programs
	Built on battle-tested POSIX system calls

Quick Installation
def deps do
  [
    {:exile, "~> x.x.x"} # Replace with latest version
  ]
end
Build Exile in its target environment. For containers, keep deps and _build
separate from the host to avoid reusing incompatible native binaries.
The native build always recompiles both binaries, but Mix may skip an already
compiled dependency. To force a rebuild in the target environment:
mix deps.compile exile --force

Quick Start Examples
Basic Command Execution
# Simple output
Exile.stream!(~w(echo Hello World!))
|> Enum.into("") # "Hello World!\n"

# With input to stdin
Exile.stream!(~w(cat), input: ["Hello ", "Back!"])
|> Enum.into("") # "Hello Back!"

# Stream as input
input_stream = Stream.map(1..10, fn num -> "#{num}\n" end)
Exile.stream!(~w(cat), input: input_stream)
|> Enum.into("")  # "1\n2\n3\n4\n5\n6\n7\n8\n9\n10\n"

# With stderr
Exile.stream!(["sh", "-c", "echo stdout && echo stderr >&2"], stderr: :consume)
|> Enum.to_list()  # [{:stdout, "stdout\n"}, {:stderr, "stderr\n"}]

# With stderr redirected to stdout
Exile.stream!(["sh", "-c", "echo stdout && echo stderr >&2"], stderr: :redirect_to_stdout)
|> Enum.to_list()  # ["stdout\nstderr\n"]
Why Exile?
The Problem with Ports
Traditional Elixir ports have several limitations:
	No back-pressure → memory exhaustion with large outputs
	Can't selectively close stdin
	Potential zombie processes
	Message-box flooding

Exile's Solution
Exile solves these by:
	Using non-blocking async I/O
	Implementing proper back-pressure
	Providing fine-grained stream control
	Handling process cleanup
	Zero external dependencies

Performance Comparison
Memory usage when reading from /dev/random:
With Port:
# Memory grows unbounded!
Port.open({:spawn_executable, "/bin/cat"}, [{:args, ["/dev/random"]}, {:line, 10}, :binary, :use_stdio])
[image: Port memory consumption]
With Exile:
# Stable memory usage
Exile.stream!(~w(cat /dev/random))
|> Enum.each(fn data ->
  IO.puts(IO.iodata_length(data))
end)
[image: Exile memory consumption]
Advanced Examples
Working with Large Data Streams
# Process large data with controlled chunk size
Exile.stream!(~w(cat huge_file.log), max_chunk_size: 65536)
|> Stream.map(&process_batch/1)
|> Stream.run()

# Handle infinite streams
infinite_stream = Stream.repeatedly(fn -> "data\n" end)
Exile.stream!(~w(cat), input: infinite_stream, ignore_epipe: true) # we need to ignore epipe since we are terminating the program before the input completes
|> Stream.take(3)
|> Enum.into("") # "data\ndata\n..."
Media Processing
# Extract audio from video
Exile.stream!(~w(ffmpeg -i pipe:0 -f mp3 pipe:1), input: File.stream!("video.mkv", [], 65_535))
|> Stream.into(File.stream!("audio.mp3"))
|> Stream.run()

# Convert video format with progress on stderr
Exile.stream!(["ffmpeg", "-i", "input.mp4", "-c:v", "libx264", "pipe:1"], stderr: :consume)
|> Enum.each(fn
  {:stdout, data} -> File.write!("output.mp4", data, [:append])
  {:stderr, data} -> IO.write(:stderr, data) # Show progress
end)
Exit Status Handling
# Using stream!/2 (raises on error non-zero exit status)
try do
  Exile.stream!(["sh", "-c", "exit 10"])
  |> Enum.to_list()
rescue
  e in Exile.Stream.AbnormalExit ->
    IO.puts("Failed with status: #{e.exit_status}")
end # "Failed with status: 10"

# Using stream/2 (returns exit status)
Exile.stream(["sh", "-c", "exit 10"])
|> Enum.to_list()  # [..., {:exit, {:status, 10}}]
Wait for Input Close
# base64 waits for input EOF before producing output
Exile.stream!(~w(base64), input: ["abcdef"])
|> Enum.into("") # "YWJjZGVm\n"
Collectable as input (Callback)
# Using input callback
Exile.stream!(~w(cat), input: fn sink ->
  Stream.repeatedly(fn -> "data\n" end)
  |> Stream.take(2)
  |> Stream.into(sink)
  |> Stream.run()
end)
|> Enum.into("") # "data\ndata\n"
Alternative Libraries
For simpler use cases where NIF-based solutions aren't preferred, consider using ExCmd, which provides similar functionality using pure Elixir.
Support & Contribution
	Documentation
	GitHub Issues

License
Copyright (c) 2020-2025 Akash Hiremath.
Released under Apache License 2.0. See LICENSE for details.


  

    LICENSE

                             Apache License
                       Version 2.0, January 2004
                    http://www.apache.org/licenses/
   TERMS AND CONDITIONS FOR USE, REPRODUCTION, AND DISTRIBUTION
	Definitions.
"License" shall mean the terms and conditions for use, reproduction,
and distribution as defined by Sections 1 through 9 of this document.
"Licensor" shall mean the copyright owner or entity authorized by
the copyright owner that is granting the License.
"Legal Entity" shall mean the union of the acting entity and all
other entities that control, are controlled by, or are under common
control with that entity. For the purposes of this definition,
"control" means (i) the power, direct or indirect, to cause the
direction or management of such entity, whether by contract or
otherwise, or (ii) ownership of fifty percent (50%) or more of the
outstanding shares, or (iii) beneficial ownership of such entity.
"You" (or "Your") shall mean an individual or Legal Entity
exercising permissions granted by this License.
"Source" form shall mean the preferred form for making modifications,
including but not limited to software source code, documentation
source, and configuration files.
"Object" form shall mean any form resulting from mechanical
transformation or translation of a Source form, including but
not limited to compiled object code, generated documentation,
and conversions to other media types.
"Work" shall mean the work of authorship, whether in Source or
Object form, made available under the License, as indicated by a
copyright notice that is included in or attached to the work
(an example is provided in the Appendix below).
"Derivative Works" shall mean any work, whether in Source or Object
form, that is based on (or derived from) the Work and for which the
editorial revisions, annotations, elaborations, or other modifications
represent, as a whole, an original work of authorship. For the purposes
of this License, Derivative Works shall not include works that remain
separable from, or merely link (or bind by name) to the interfaces of,
the Work and Derivative Works thereof.
"Contribution" shall mean any work of authorship, including
the original version of the Work and any modifications or additions
to that Work or Derivative Works thereof, that is intentionally
submitted to Licensor for inclusion in the Work by the copyright owner
or by an individual or Legal Entity authorized to submit on behalf of
the copyright owner. For the purposes of this definition, "submitted"
means any form of electronic, verbal, or written communication sent
to the Licensor or its representatives, including but not limited to
communication on electronic mailing lists, source code control systems,
and issue tracking systems that are managed by, or on behalf of, the
Licensor for the purpose of discussing and improving the Work, but
excluding communication that is conspicuously marked or otherwise
designated in writing by the copyright owner as "Not a Contribution."
"Contributor" shall mean Licensor and any individual or Legal Entity
on behalf of whom a Contribution has been received by Licensor and
subsequently incorporated within the Work.

	Grant of Copyright License. Subject to the terms and conditions of
this License, each Contributor hereby grants to You a perpetual,
worldwide, non-exclusive, no-charge, royalty-free, irrevocable
copyright license to reproduce, prepare Derivative Works of,
publicly display, publicly perform, sublicense, and distribute the
Work and such Derivative Works in Source or Object form.

	Grant of Patent License. Subject to the terms and conditions of
this License, each Contributor hereby grants to You a perpetual,
worldwide, non-exclusive, no-charge, royalty-free, irrevocable
(except as stated in this section) patent license to make, have made,
use, offer to sell, sell, import, and otherwise transfer the Work,
where such license applies only to those patent claims licensable
by such Contributor that are necessarily infringed by their
Contribution(s) alone or by combination of their Contribution(s)
with the Work to which such Contribution(s) was submitted. If You
institute patent litigation against any entity (including a
cross-claim or counterclaim in a lawsuit) alleging that the Work
or a Contribution incorporated within the Work constitutes direct
or contributory patent infringement, then any patent licenses
granted to You under this License for that Work shall terminate
as of the date such litigation is filed.

	Redistribution. You may reproduce and distribute copies of the
Work or Derivative Works thereof in any medium, with or without
modifications, and in Source or Object form, provided that You
meet the following conditions:
(a) You must give any other recipients of the Work or
Derivative Works a copy of this License; and
(b) You must cause any modified files to carry prominent notices
stating that You changed the files; and
(c) You must retain, in the Source form of any Derivative Works
that You distribute, all copyright, patent, trademark, and
attribution notices from the Source form of the Work,
excluding those notices that do not pertain to any part of
the Derivative Works; and
(d) If the Work includes a "NOTICE" text file as part of its
distribution, then any Derivative Works that You distribute must
include a readable copy of the attribution notices contained
within such NOTICE file, excluding those notices that do not
pertain to any part of the Derivative Works, in at least one
of the following places: within a NOTICE text file distributed
as part of the Derivative Works; within the Source form or
documentation, if provided along with the Derivative Works; or,
within a display generated by the Derivative Works, if and
wherever such third-party notices normally appear. The contents
of the NOTICE file are for informational purposes only and
do not modify the License. You may add Your own attribution
notices within Derivative Works that You distribute, alongside
or as an addendum to the NOTICE text from the Work, provided
that such additional attribution notices cannot be construed
as modifying the License.
You may add Your own copyright statement to Your modifications and
may provide additional or different license terms and conditions
for use, reproduction, or distribution of Your modifications, or
for any such Derivative Works as a whole, provided Your use,
reproduction, and distribution of the Work otherwise complies with
the conditions stated in this License.

	Submission of Contributions. Unless You explicitly state otherwise,
any Contribution intentionally submitted for inclusion in the Work
by You to the Licensor shall be under the terms and conditions of
this License, without any additional terms or conditions.
Notwithstanding the above, nothing herein shall supersede or modify
the terms of any separate license agreement you may have executed
with Licensor regarding such Contributions.

	Trademarks. This License does not grant permission to use the trade
names, trademarks, service marks, or product names of the Licensor,
except as required for reasonable and customary use in describing the
origin of the Work and reproducing the content of the NOTICE file.

	Disclaimer of Warranty. Unless required by applicable law or
agreed to in writing, Licensor provides the Work (and each
Contributor provides its Contributions) on an "AS IS" BASIS,
WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or
implied, including, without limitation, any warranties or conditions
of TITLE, NON-INFRINGEMENT, MERCHANTABILITY, or FITNESS FOR A
PARTICULAR PURPOSE. You are solely responsible for determining the
appropriateness of using or redistributing the Work and assume any
risks associated with Your exercise of permissions under this License.

	Limitation of Liability. In no event and under no legal theory,
whether in tort (including negligence), contract, or otherwise,
unless required by applicable law (such as deliberate and grossly
negligent acts) or agreed to in writing, shall any Contributor be
liable to You for damages, including any direct, indirect, special,
incidental, or consequential damages of any character arising as a
result of this License or out of the use or inability to use the
Work (including but not limited to damages for loss of goodwill,
work stoppage, computer failure or malfunction, or any and all
other commercial damages or losses), even if such Contributor
has been advised of the possibility of such damages.

	Accepting Warranty or Additional Liability. While redistributing
the Work or Derivative Works thereof, You may choose to offer,
and charge a fee for, acceptance of support, warranty, indemnity,
or other liability obligations and/or rights consistent with this
License. However, in accepting such obligations, You may act only
on Your own behalf and on Your sole responsibility, not on behalf
of any other Contributor, and only if You agree to indemnify,
defend, and hold each Contributor harmless for any liability
incurred by, or claims asserted against, such Contributor by reason
of your accepting any such warranty or additional liability.

Exile is an alternative for beam ports
with back-pressure and non-blocking IO.
Quick Start
Run a command and read from stdout
iex> Exile.stream!(~w(echo Hello))
...> |> Enum.into("") # collect as string
"Hello\n"
Run a command with list of strings as input
iex> Exile.stream!(~w(cat), input: ["Hello", " ", "World"])
...> |> Enum.into("") # collect as string
"Hello World"
Run a command with input as Stream
iex> input_stream = Stream.map(1..10, fn num -> "#{num} " end)
iex> Exile.stream!(~w(cat), input: input_stream)
...> |> Enum.into("")
"1 2 3 4 5 6 7 8 9 10 "
Run a command with input as infinite stream
# create infinite stream
iex> input_stream = Stream.repeatedly(fn -> "A" end)
iex> binary =
...>   Exile.stream!(~w(cat), input: input_stream, ignore_epipe: true) # we need to ignore epipe since we are terminating the program before the input completes
...>   |> Stream.take(2) # we must limit since the input stream is infinite
...>   |> Enum.into("")
iex> is_binary(binary)
true
iex> "AAAAA" <> _ = binary
Run a command with input Collectable
# Exile calls the callback with a sink where the process can push the data
iex> Exile.stream!(~w(cat), input: fn sink ->
...>   Stream.map(1..10, fn num -> "#{num} " end)
...>   |> Stream.into(sink) # push to the external process
...>   |> Stream.run()
...> end)
...> |> Stream.take(100) # we must limit since the input stream is infinite
...> |> Enum.into("")
"1 2 3 4 5 6 7 8 9 10 "
When the command wait for the input stream to close
# base64 command wait for the input to close and writes data to stdout at once
iex> Exile.stream!(~w(base64), input: ["abcdef"])
...> |> Enum.into("")
"YWJjZGVm\n"
stream!/2 raises non-zero exit as error
iex> Exile.stream!(["sh", "-c", "echo 'foo' && exit 10"])
...> |> Enum.to_list()
** (Exile.Stream.AbnormalExit) program exited with exit status: 10
stream/2 variant returns exit status as last element
iex> Exile.stream(["sh", "-c", "echo 'foo' && exit 10"])
...> |> Enum.to_list()
[
  "foo\n",
  {:exit, {:status, 10}} # returns exit status of the program as last element
]
You can fetch exit_status from the error for stream!/2
iex> try do
...>   Exile.stream!(["sh", "-c", "exit 10"])
...>   |> Enum.to_list()
...> rescue
...>   e in Exile.Stream.AbnormalExit ->
...>     e.exit_status
...> end
10
With max_chunk_size set
iex> data =
...>   Exile.stream!(~w(cat /dev/urandom), max_chunk_size: 100, ignore_epipe: true)
...>   |> Stream.take(5)
...>   |> Enum.into("")
iex> byte_size(data)
500
When input and output run at different rate
iex> input_stream = Stream.map(1..1000, fn num -> "X #{num} X\n" end)
iex> Exile.stream!(~w(grep 250), input: input_stream)
...> |> Enum.into("")
"X 250 X\n"
With stderr set to :redirect_to_stdout
iex> Exile.stream!(["sh", "-c", "echo foo; echo bar >> /dev/stderr"], stderr: :redirect_to_stdout)
...> |> Enum.into("")
"foo\nbar\n"
With stderr set to :consume
iex> Exile.stream!(["sh", "-c", "echo foo; echo bar >> /dev/stderr"], stderr: :consume)
...> |> Enum.to_list()
[{:stdout, "foo\n"}, {:stderr, "bar\n"}]
With stderr set to :disable
iex> Exile.stream!(["sh", "-c", "echo foo; echo bar >> /dev/stderr"], stderr: :disable)
...> |> Enum.to_list()
["foo\n"]
For more details about stream API, see Exile.stream!/2 and Exile.stream/2.
For more details about inner working, please check Exile.Process
documentation.

        stream(cmd_with_args, opts \\ [])

      


        Same as Exile.stream!/2 but the program exit status is passed as last
element of the stream.



    


    
      
        stream!(cmd_with_args, opts \\ [])

      


        Runs the command with arguments and return an the stdout as lazily
Enumerable stream, similar to Stream.

          @type collectable_func() :: (Collectable.t() -> any())

          @spec stream([String.t(), ...],
  input: Enum.t() | collectable_func(),
  exit_timeout: timeout(),
  cancel_timeout: timeout(),
  stderr: :console | :redirect_to_stdout | :disable | :consume,
  ignore_epipe: boolean(),
  max_chunk_size: pos_integer()
) :: Exile.Stream.t()


      


Same as Exile.stream!/2 but the program exit status is passed as last
element of the stream.
The last element will be of the form {:exit, term()}. term will be a
positive integer in case of normal exit and :epipe in case of epipe error
Early termination can still raise Exile.Stream.AbnormalExit; ignore_epipe applies.
See Exile.stream!/2 documentation for details about the options and
examples.

          @spec stream!([String.t(), ...],
  input: Enum.t() | collectable_func(),
  exit_timeout: timeout(),
  cancel_timeout: timeout(),
  stderr: :console | :redirect_to_stdout | :disable | :consume,
  ignore_epipe: boolean(),
  max_chunk_size: pos_integer()
) :: Exile.Stream.t()


      


Runs the command with arguments and return an the stdout as lazily
Enumerable stream, similar to Stream.
First parameter must be a list containing command with arguments.
Example: ["cat", "file.txt"].
Options
	input - Input can be either an Enumerable or a function which accepts Collectable.
	Enumerable:
# List
Exile.stream!(~w(base64), input: ["hello", "world"]) |> Enum.to_list()
# Stream
Exile.stream!(~w(cat), input: File.stream!("log.txt", [], 65_536)) |> Enum.to_list()

	Collectable:
If the input in a function with arity 1, Exile will call that function
with a Collectable as the argument. The function must push input to this
collectable. Return value of the function is ignored.
Exile.stream!(~w(cat), input: fn sink -> Enum.into(1..100, sink, &to_string/1) end)
|> Enum.to_list()
By defaults no input is sent to the command.


Input exceptions, throws, and explicit exits propagate to the enumerating caller
after cleanup. External exit signals are not intercepted.

	exit_timeout - Wait for program exit after output EOF. Positive milliseconds
or :infinity; defaults to 5000.

	cancel_timeout - Timeout per cleanup step on early halt or failure: command
exit, then input-task completion. Positive milliseconds or :infinity; defaults
to 1000, independently of exit_timeout. Total cleanup may take twice this timeout.
Unfinished input tasks are killed, which may skip their cleanup callbacks.

	max_chunk_size - Maximum size of iodata chunk emitted by the stream.
Chunk size can be less than the max_chunk_size depending on the amount of
data available to be read. Defaults to 65_535

	stderr  -  different ways to handle stderr stream.
	:console  -  stderr output is redirected to console (Default)
	:redirect_to_stdout  -  stderr output is redirected to stdout
	:disable  -  stderr output is redirected /dev/null suppressing all output
	:consume  -  connects stderr for the consumption. The output stream will contain stderr
data along with stdout. Stream data will be either {:stdout, iodata} or {:stderr, iodata}
to differentiate different streams. See example below.

 See :stderr for more details and issues associated with them.

	ignore_epipe - When set to true, reader can exit early without raising error.
Typically writer gets EPIPE error on write when program terminate prematurely.
With ignore_epipe set to true this error will be ignored. This can be used to
match UNIX shell default behaviour. EPIPE is the error raised when the reader finishes
the reading and close output pipe before command completes. Defaults to false.


Remaining options are passed to Exile.Process.start_link/2
If program exits with non-zero exit status or :epipe then Exile.Stream.AbnormalExit
error will be raised with exit_status field set.
Consumer exceptions and stack traces are preserved; cleanup failures are logged.
Examples
Exile.stream!(~w(ffmpeg -i pipe:0 -f mp3 pipe:1), input: File.stream!("music_video.mkv", [], 65_535))
|> Stream.into(File.stream!("music.mp3"))
|> Stream.run()
Stream with stderr redirected to stdout
Exile.stream!(["sh", "-c", "echo foo; echo bar >> /dev/stderr"], stderr: :redirect_to_stdout)
|> Stream.map(&IO.write/1)
|> Stream.run()
Stream with stderr
Exile.stream!(~w(ffmpeg -i pipe:0 -f mp3 pipe:1),
  input: File.stream!("music_video.mkv", [], 65_535),
  stderr: :consume
)
|> Stream.transform(
  fn ->
    File.open!("music.mp3", [:write, :binary])
  end,
  fn elem, file ->
    case elem do
      {:stdout, data} ->
        # write stdout data to a file
        :ok = IO.binwrite(file, data)

      {:stderr, msg} ->
        # write stderr output to console
        :ok = IO.write(msg)
    end

    {[], file}
  end,
  fn file ->
    :ok = File.close(file)
  end
)
|> Stream.run()

GenServer which wraps spawned external command.
Use Exile.stream!/1 over using this. Use this only if you are
familiar with life-cycle and need more control of the IO streams
and OS process.
Comparison with Port
	it is demand driven. User explicitly has to read the command
output, and the progress of the external command is controlled
using OS pipes. Exile never load more output than we can consume,
so we should never experience memory issues

	it can close stdin while consuming output

	tries to handle zombie process by attempting to cleanup
external process. Note that there is no middleware involved
with exile so it is still possible to endup with zombie process.

	selectively consume stdout and stderr


Internally Exile uses non-blocking asynchronous system calls
to interact with the external process. It does not use port's
message based communication, instead uses raw stdio and NIF.
Uses asynchronous system calls for IO. Most of the system
calls are non-blocking, so it should not block the beam
schedulers. Make use of dirty-schedulers for IO
Introduction
Exile.Process is a process based wrapper around the external
process. It is similar to port as an entity but the interface is
different. All communication with the external process must happen
via Exile.Process interface.
Exile process life-cycle tied to external process and owners. All
system resources such are open file-descriptors, external process
are cleaned up when the Exile.Process dies.
Owner
Each Exile.Process has an owner. And it will be the process which
created it (via Exile.Process.start_link/2). Process owner can not
be changed.
Owner process will be linked to the Exile.Process. So when the
exile process is dies abnormally the owner will be killed too or
visa-versa. Owner process should avoid trapping the exit signal, if
you want avoid the caller getting killed, create a separate process
as owner to run the command and monitor that process.
Only owner can get the exit status of the command, using
Exile.Process.await_exit/2. All exile processes MUST be
awaited.  Exit status or reason is ALWAYS sent to the owner. It
is similar to Task. If the
owner exit without await_exit, the exile process will be killed,
but if the owner continue without await_exit then the exile
process will linger around till the process exit.
iex> alias Exile.Process
iex> {:ok, p} = Process.start_link(~w(echo hello))
iex> Process.read(p, 100)
{:ok, "hello\n"}
iex> Process.read(p, 100) # read till we get :eof
:eof
iex> Process.await_exit(p)
{:ok, 0}
Pipe & Pipe Owner
Standard IO pipes/channels/streams of the external process such as
STDIN, STDOUT, STDERR are called as Pipes. User can either write or
read data from pipes.
Each pipe has an owner process and only that process can write or
read from the exile process. By default the process who created the
exile process is the owner of all the pipes. Pipe owner can be
changed using Exile.Process.change_pipe_owner/3.
Pipe owner is monitored and the pipes are closed automatically when
the pipe owner exit. Pipe Owner can close the pipe early using
Exile.Process.close_stdin/1 etc.
Exile.Process.await_exit/2 closes all of the caller owned pipes by
default.
iex> {:ok, p} = Process.start_link(~w(cat))
iex> writer = Task.async(fn ->
...>   :ok = Process.change_pipe_owner(p, :stdin, self())
...>   Process.write(p, "Hello World")
...> end)
iex> Task.await(writer)
:ok
iex> Process.read(p, 100)
{:ok, "Hello World"}
iex> Process.await_exit(p)
{:ok, 0}
Pipe Operations
Only Pipe owner can read or write date to the owned pipe.
All Pipe operations (read/write) blocks the caller as a mechanism
to put back-pressure, and this also makes the API simpler.
This is same as how command-line programs works on the shell,
along with pipes in-between, Example: cat larg-file | grep "foo".
Internally Exile uses asynchronous IO APIs to avoid blocking VM
(by default NIF calls blocks the VM scheduler),
so you can open several pipes and do concurrent IO operations without
blocking VM.
stderr
by default is :stderr is connected to console, data written to
stderr will appear on the console.
You can change the behavior by setting :stderr:
	:console  -  stderr output is redirected to console (Default)
	:redirect_to_stdout  -  stderr output is redirected to stdout
	:consume  -  stderr output read separately, allowing you to consume it separately from stdout. See below for more details
	:disable  -  stderr output is redirected /dev/null suppressing all output. See below for more details.

Using redirect_to_stdout
stderr data will be redirected to stdout. When you read stdout
you will see both stdout & stderr combined and you won't be
able differentiate stdout and stderr separately.
This is similar to :stderr_to_stdout option present in
Ports.
Unexpected Behaviors
On many systems, stdout and stderr are separated. And between
the source program to Exile, via the kernel, there are several places
that may buffer data, even temporarily, before Exile is ready
to read them. There is no enforced ordering of the readiness of
these independent buffers for Exile to make use of.
This can result in unexpected behavior, including:
	mangled data, for example, UTF-8 characters may be incomplete
until an additional buffered segment is released on the same
source
	raw data, where binary data sent on one source, is incompatible
with data sent on the other source.
	interleaved data, where what appears to be synchronous, is not

In short, the two streams might be combined at arbitrary byte position
leading to above mentioned issue.
Most well-behaved command-line programs are unlikely to exhibit
this, but you need to be aware of the risk.
A good example of this unexpected behavior is streaming JSON from
an external tool to Exile, where normal JSON output is expected on
stdout, and errors or warnings via stderr. In the case of an
unexpected error, the stdout stream could be incomplete, or the
stderr message might arrive before the closing data on the stdout
stream.
Using consume
stderr data can be consumed separately using
Exile.Process.read_stderr/2. Special function
Exile.Process.read_any/2 can be used to read from either stdout or
stderr whichever has the data available. See the examples for more
details.
Unexpected Behaviors
When set, the stderr output MUST be consumed to
avoid blocking the external program when stderr buffer is full.
Reading from stderr using read_stderr
# write "Hello" to stdout and "World" to stderr
iex> script = Enum.join(["echo Hello", "echo World >&2"], "\n")
iex> {:ok, p} = Process.start_link(["sh", "-c", script], stderr: :consume)
iex> Process.read(p, 100)
{:ok, "Hello\n"}
iex> Process.read_stderr(p, 100)
{:ok, "World\n"}
iex> Process.await_exit(p)
{:ok, 0}
Reading using read_any
# write "Hello" to stdout and "World" to stderr
iex> script = Enum.join(["echo Hello", "echo World >&2"], "\n")
iex> {:ok, p} = Process.start_link(["sh", "-c", script], stderr: :consume)
iex> Process.read_any(p)
{:ok, {:stdout, "Hello\n"}}
iex> Process.read_any(p)
{:ok, {:stderr, "World\n"}}
iex> Process.await_exit(p)
{:ok, 0}
Process Termination
When owner does (normally or abnormally) the Exile process always
terminated irrespective of pipe status or process status. External
process get a chance to terminate gracefully, if that fail it will
be killed.
If owner calls await_exit then the owner owned pipes are closed
and we wait for external process to terminate, if the process
already terminated then call returns immediately with exit
status. Else command will be attempted to stop gracefully following
the exit sequence based on the timeout value (5s by default).
If owner calls await_exit with timeout as :infinity then
Exile does not attempt to forcefully stop the external command and
wait for command to exit on itself. The await_exit call can be blocked
indefinitely waiting for external process to terminate.
If external process exit on its own, exit status is collected and
Exile process will wait for owner to close pipes. Most commands exit
with pipes are closed, so just ensuring to close pipes when works is
done should be enough.
Example of process getting terminated by SIGTERM signal
# sleep command does not watch for stdin or stdout, so closing the
# pipe does not terminate the sleep command.
iex> {:ok, p} = Process.start_link(~w(sleep 100000000)) # sleep indefinitely
iex> Process.await_exit(p, 100) # ensure `await_exit` finish within `100ms`. By default it waits for 5s
{:ok, 143} # 143 is the exit status when command exit due to SIGTERM
Examples
Run a command without any input or output
iex> {:ok, p} = Process.start_link(["sh", "-c", "exit 1"])
iex> Process.await_exit(p)
{:ok, 1}
Single process reading and writing to the command
# bc is a calculator, which reads from stdin and writes output to stdout
iex> {:ok, p} = Process.start_link(~w(bc))
iex> Process.write(p, "1 + 1\n") # there must be new-line to indicate the end of the input line
:ok
iex> Process.read(p)
{:ok, "2\n"}
iex> Process.write(p, "2 * 10 + 1\n")
:ok
iex> Process.read(p)
{:ok, "21\n"}
# We must close stdin to signal the `bc` command that we are done.
# since `await_exit` implicitly closes the pipes, in this case we don't have to
iex> Process.await_exit(p)
{:ok, 0}
Running a command which flush the output on stdin close. This is not
supported by Erlang/Elixir ports.
# `base64` command reads all input and writes encoded output when stdin is closed.
iex> {:ok, p} = Process.start_link(~w(base64))
iex> Process.write(p, "abcdef")
:ok
iex> Process.close_stdin(p) # we can selectively close stdin and read all output
:ok
iex> Process.read(p)
{:ok, "YWJjZGVm\n"}
iex> Process.read(p) # typically it is better to read till we receive :eof when we are not sure how big the output data size is
:eof
iex> Process.await_exit(p)
{:ok, 0}
Read and write to pipes in separate processes
iex> {:ok, p} = Process.start_link(~w(cat))
iex> writer = Task.async(fn ->
...>   :ok = Process.change_pipe_owner(p, :stdin, self())
...>   Process.write(p, "Hello World")
...>   # no need to close the pipe explicitly here. Pipe will be closed automatically when process exit
...> end)
iex> reader = Task.async(fn ->
...>   :ok = Process.change_pipe_owner(p, :stdout, self())
...>   Process.read(p)
...> end)
iex> :timer.sleep(500) # wait for the reader and writer to change pipe owner, otherwise `await_exit` will close the pipes before we change pipe owner
iex> Process.await_exit(p, :infinity) # let the reader and writer take indefinite time to finish
{:ok, 0}
iex> Task.await(writer)
:ok
iex> Task.await(reader)
{:ok, "Hello World"}

Startup is asynchronous. If it fails, the server exits with Exile.Process.Error.
Connecting to the helper and receiving its pipes each have a two-second timeout.
These timeouts do not limit the command's runtime.
Options
	:cd - Working directory.
	:env - A map or list of {name, value} environment variables.
	:stderr - :console (default), :redirect_to_stdout, :disable, or
:consume. With :consume, read stderr to avoid blocking the command.
See stderr handling for details.

